MothLibrary

เคยมั้ย บางครั้งก็รู้สึกว่าร่างกายตัวเองมาถึงจุดที่ “ไม่ไหวแล้ว” ทั้งปวดหลัง เหนื่อยง่าย แค่เดินขึ้นบันไดก็หอบ แถมรู้สึกว่าร่างกายพังจากข้างในช้า ๆ

นั่นแหละ คือจุดเริ่มต้นของโปรเจกต์นี้

เริ่มจากวันหนึ่งหลังเลิกงานที่เหนื่อยจนไม่อยากลุกจากโซฟา แล้วก็คิดได้ว่าต้องทำอะไรสักอย่าง ไม่งั้นร่างกาย (และจิตใจ) คงแย่ไปเรื่อย ๆ แน่ และนั่นคือวันที่เราเริ่มทำ Tracker ง่าย ๆ ไว้ติดตามการดูแลสุขภาพของตัวเอง ทำไปทำมา ก็กลายเป็นโปรเจกต์ที่จริงจังขึ้นเรื่อย ๆ จนได้เวอร์ชันที่พอใจที่สุด

Table of Contents

• Project Overview
• Why I Built This Project
• Tools
• Let’s Start
  • Step 1: กำหนดตัวชี้วัด (Identify Key Metrics)
  • Step 2: ออกแบบระบบการให้คะแนน (Scoring System)
  • Step 3: สร้างแถบความคืบหน้า (Progress Bar Visualization)
  • Step 4: ระบบรักษาวินัย (Streak & Summary)
  • Step 4: เติมเต็มใจให้สปาร์กจอย (Weekly Check-ins & Reflections)
  • Step 6: เชื่อมโยงข้อมูลสู่ภาพรวม (Data Consolidation)
  • Step 8: สรุปภาพรวม (Yearly Insights & Visual Analytics)
    • 1. สร้าง Yearly Dashboard ใน Google Sheets
    • 2. สร้างแดชบอร์ดสรุปภาพรวม ใน Looker Studio
• Outcome
• Get Your Own Tracker

Project Overview

โปรเจกต์ Glow Up Tracker คือ Habit Tracker แบบรายวัน ที่จะช่วยให้เราติดตามการดูแลสุขภาพของตัวเองได้ครบทุกด้านที่ต้องการ ทั้งการกิน การนอน การออกกำลังกาย และอารมณ์

มาพร้อม Mini Charts แบบเรียบง่าย ช่วยสรุปความคืบหน้าในเดือนนั้น ตรวจสอบ Progress การดูแลตัวเองได้ทั้งแบบรายเดือนและรายปี มีพื้นที่ให้บันทึกอารมณ์แต่ละวัน และจด Reflection ประจำเดือนได้อย่างอิสระ

Why I Built This Project

สิ่งที่ทำให้เริ่มโปรเจกต์นี้คืออยากติดตามพฤติกรรมของตัวเองแบบง่าย ๆ เพื่อเช็กว่าวันนี้ “เรารักตัวเองแล้วหรือยัง” อยากเห็นทุกอย่างเป็นข้อมูลที่ติดตามและวัดผลได้ เพราะตัวเองไม่มีระบบวัดพฤติกรรมสุขภาพรายวันอย่างอื่น (bujo, planner, etc.) ทำให้ไม่มีข้อมูลที่เอาไปติดตามได้จริง

นอกจากนี้ยังตั้งใจให้ Glow Up Tracker ใช้เพื่อ:

• บันทึกพฤติกรรมรายวันอย่างเป็นระบบ
• สรุปผลแบบรายเดือนเพื่อเห็น trend
• ใช้ Google Sheets เป็นฐานข้อมูล
• สร้าง Visualization ที่ชัดเจน เข้าใจง่าย

Tools

• Google Sheets
• Looker Studio

Let’s Start

Step 1: กำหนดตัวชี้วัด (Identify Key Metrics)

เริ่มต้นด้วยการตั้งคำถามว่า “อะไรคือสิ่งสำคัญที่เราอยากเปลี่ยนแปลง?” ซึ่งเรามีพฤติกรรมที่อยากปรับเปลี่ยนหลายอย่าง แต่โดยรวมแล้วแบ่งเป็น 4 ด้าน คือ

• Physical Health: การกินอาหาร การดื่มน้ำ การออกกำลังกาย
• Rest: คุณภาพการนอน
• Skincare: การบำรุงผิว
• Mental Health: การบันทึกอารมณ์ความรู้สึก (Mood Tracker)

สร้างตาราง เพิ่มหัวข้อที่อยากติดตามพฤติกรรมแยกเป็นคอลัมน์ ใส่วันที่ให้เรียบร้อย

Step 2: ออกแบบระบบการให้คะแนน (Scoring System)

ใช้ระบบ Checkbox และ Emoji เข้ามาช่วย เพื่อให้เราติดตามพฤติกรรมไปพร้อมกับเก็บข้อมูลได้แบบเรียลไทม์ นอกจากนี้ยังเพิ่มความสนุกฟีล Gamification เข้ามาด้วยระบบสะสมดาว

• สะสมดาว: กำหนดเป้าหมายในแต่ละวันเป็น 9 หัวข้อ หากทำสำเร็จให้ติ๊ก Checkbox ยิ่งทำสำเร็จมาก ดาวที่ได้รับในวันนั้นจะมากขึ้นด้วย (มีตั้งแต่ 1 – 5 ดาว)

=ARRAYFORMULA(REPT("⭐", COUNTIF(C9:K9, TRUE)/9*5))

อธิบายฟังก์ชัน

1. COUNTIF(C9:K9, TRUE)

• นับจำนวนเซลล์ในช่วง C9:K9 ที่มีค่าเป็น TRUE
• สมมติว่ามี TRUE อยู่ 6 ช่อง → ผลลัพธ์คือ 6

2. /9*5

ช่วง C9:K9 มีทั้งหมด 9 ช่อง เพราะฉะนั้นฟังก์ชันนี้จะแปลง “จำนวน TRUE” ให้เท่ากับ “คะแนนเต็ม 5 ดาว”

ตัวอย่าง: ถ้ามี TRUE = 6

$$6\mathrm{/}9\times 5=3.33$$

หมายความว่าถ้าเราทำ Daily Log สำเร็จ 6 อย่าง ก็จะได้ดาว 3.33 ดาว

3. REPT("⭐", … )

ฟังก์ชัน REPT จะทำซ้ำตัวอักษรตามจำนวนที่กำหนด แต่! REPT ก็จะช่วยตัดทศนิยมออกด้วย เช่น 3.33 จะกลายเป็น 3

ดังนั้นผลลัพธ์ที่เราได้ก็คือ…

• Mood Emoji: ใช้ Dropdown list เลือกใส่อีโมจิตามใจชอบ ของเราจะมี 5 แบบ แทนอารมณ์ 5 อย่าง พร้อมใส่สีเอาไว้ด้วยเพื่อความสวยงามเวลาบันทึกอารมณ์ครบทั้งเดือน

Step 3: สร้างแถบความคืบหน้า (Progress Bar Visualization)

สร้างตาราง Monthly Summary เพื่อติดตามความคืบหน้าของพฤติกรรมที่เราอยากปรับ โดยเราเลือกใช้ Sparkline และตัวเลขเปอร์เซ็นต์มาแสดงผล

• Visual Check: เมื่อติ๊กถูกใน Checkbox ก็จะเห็นความคืบหน้าในแต่ละวันได้ทันที โดยจะแสดงผลเป็น Bar Chart และเปอร์เซ็นต์

=SPARKLINE(COUNTIF(C9:C39, TRUE), {"charttype", "bar"; "max", COUNTA(B9:B39); "color1", "#ADD8E6"})

=COUNTIF(C9:C39, TRUE) / COUNTA(B9:B39)

อธิบายฟังก์ชัน

1. COUNTIF(C9:C39, TRUE)

• นับจำนวนเซลล์ในช่วง C9:C39 ที่มีค่าเป็น TRUE
• สมมติว่ามี TRUE = 18 → ผลลัพธ์คือ 18

นี่คือ “จำนวนงานที่ทำสำเร็จแล้ว”

2. COUNTA(B9:B39)

• นับจำนวนเซลล์ที่ ไม่ว่าง ในช่วง B9:B39
• โดยทั่วไปคอลัมน์ B มักเป็น “รายการทั้งหมดที่ต้องทำ”
• ถ้ามีรายการทั้งหมด 31 รายการ → ผลลัพธ์คือ 31

นี่คือ “จำนวนงานทั้งหมดที่ต้องทำ”

3. การหาร

สูตรทำงานแบบนี้:

$$\text{จำนวนงานที่ทำสำเร็จ}÷\text{จำนวนงานทั้งหมด}$$

ตัวอย่าง:

$$18÷31=0.5806$$

แปลว่า ทำสำเร็จประมาณ 58%

ผลลัพธ์ที่ได้ก็คือ…

• Average Mood: สำรวจว่าในเดือนนั้นเรารู้สึกแบบไหนมากที่สุด ด้วยการหาค่าอีโมจิที่ถูกเลือกมากที่สุดและแสดงผลลัพธ์ออกมาเมื่อเราบันทึกอารมณ์ครบทุกวัน

=IFERROR(INDEX(L9:L39, MODE(MATCH(L9:L39, L9:L39, 0))), "เจอกันสิ้นเดือน ;)")

อธิบายฟังก์ชัน

1. MATCH(L9:L39, L9:L39, 0)

• MATCH จะคืนค่า “ตำแหน่งแรกที่พบ” ของแต่ละค่าในช่วง
• ตัวเลขที่ซ้ำบ่อยที่สุด = ค่าที่เกิดบ่อยที่สุดในช่วง L9:L39
• ใช้แปลงอีโมจิเป็นค่าตำแหน่ง

2. MODE( … )

• ฟังก์ชัน MODE จะหาค่า “ตัวเลขที่เกิดบ่อยที่สุด” จากผล MATCH ที่เราแปลงไว้แล้ว
• เช่น ถ้า MATCH ให้ผล {1,2,1,4,2,1} → MODE = 1 (เพราะเลข 1 โผล่มาบ่อยสุด)

3. INDEX(L9:L39, … )

• เอาตำแหน่งที่ได้จาก MODE ไปดึงค่าจริงในช่วง L9:L39 (คอลัมน์บันทึกอารมณ์ของเรา)
• จากนั้นผลลัพธ์ที่ได้คือ จะดึงค่าจริงที่เกิดขึ้นบ่อยที่สุดออกมาโชว์

4. IFERROR( … , "เจอกันสิ้นเดือน ;)" )

• ตอนใช้ฟังก์ชันนี้ถ้ายังบันทึกอารมณ์ไม่ครบทุกวัน ค่าที่แสดงออกมาจะเป็น error เลยแก้ด้วยการใช้ฟังก์ชัน IFERROR
• เราเลือกให้แสดงข้อความน่ารัก ๆ ว่า “เจอกันสิ้นเดือน ;)” เพราะอีโมจิที่เราใช้บ่อยที่สุดจะแสดงในช่องนี้ตอนสิ้นเดือน หรือตอนที่เราบันทึกอารมณ์ครบทุกวันแล้วนั่นเอง

• Star Score: หาค่าเฉลี่ยดาวที่เราทำได้ ว่าในเดือนนั้นเราได้ดาวกี่ดวงบ่อยที่สุด (ตั้งแต่ 1 – 5 ดาว) โดยเราต้องสร้างคอลัมน์ว่างขึ้นมาก่อนแล้วใช้ฟังก์ชันเพื่อนับดาวที่ได้เป็นตัวเลข โดยนับจำนวน TRUE ในวันนั้น แปลงเป็นคะแนนเต็ม 5 แล้วปัดเป็นจำนวนเต็ม

=ARRAYFORMULA(ROUND(COUNTIF(C9:K9, TRUE)/9*5))

• จากนั้นหาว่าเราได้ดาวกี่ดวงบ่อยที่สุด เพื่อให้แสดงผลตอนสิ้นเดือน

=REPT("⭐", IFERROR(MODE(N9:N39), 0))

• Little Messege: นอกจากแสดงจำนวนดาวที่เราได้มากที่สุดในเดือนนั้นแล้ว เรายังอยากให้มีข้อความน่ารัก ๆ เป็นการ cheer up ตัวเองด้วย

=IFS(LEN(M3)=5, "Glow Up Queen 👸", OR(LEN(M3)=3, LEN(M3)=4), "Consistent Star ⭐", OR(LEN(M3)=1, LEN(M3)=2), "Reset & Restart 🌿", TRUE, "Waiting for miracle!")

Step 4: ระบบรักษาวินัย (Streak & Summary)

เมื่อสร้างตารางหลักเสร็จแล้ว ก็ออกแบบ Score Card เพื่อคำนวณ “ความต่อเนื่อง” และสรุปผลรายเดือน

• Monthly Progress: ออกแบบ Score Card ง่าย ๆ เพื่อสรุปความคืบหน้าทั้งหมดที่เราทำได้ในเดือนนี้ แสดงผลเป็นเปอร์เซ็นต์

=COUNTIF(C9:K39, TRUE) / COUNTIF(C9:K39, "<>")

อธิบายฟังก์ชัน

1. COUNTIF(C9:K39, TRUE)

• นับจำนวนเซลล์ในช่วง C9:K39 ที่มีค่าเป็น TRUE

2. COUNTIF(C9:K39, “<>”)

• นับจำนวนเซลล์ที่ ไม่ว่าง
• เครื่องหมาย <> หมายถึง “ไม่เท่ากับค่าว่าง”
• เช่น ถ้าในช่วงนั้นมีข้อมูลอยู่ 30 เซลล์ (ไม่ว่าจะเป็น TRUE, FALSE, ตัวเลข, ข้อความ) → ผลลัพธ์คือ 30

3. การหาร

จำนวน TRUE / จำนวนเซลล์ที่ไม่ว่าง

ตัวอย่าง:

• TRUE = 12
• เซลล์ไม่ว่าง = 30

ผลลัพธ์ = (12 / 30 = 0.4) → เท่ากับ 40%

• Current Streak: นับวันที่สะสมดาวได้ 3 ดาวขึ้นไป โดยจะนับไปเรื่อย ๆ แต่ถ้าวันไหนได้ 2 ดาวหรือต่ำกว่าก็จะเริ่มนับใหม่
• Longest: บันทึกจำนวน Current Streak ที่ทำได้ต่อเนื่องนานที่สุด

=LET(streak_range, O9:O39, 
     last_val, INDEX(streak_range, MAX(FILTER(ROW(streak_range)-ROW(V9)+1, streak_range<>""))), 
     IF(last_val=0, 0, COUNTIF(OFFSET(V9, MAX(FILTER(ROW(streak_range)-ROW(V9)+1, streak_range=0)), 0, ROWS(streak_range)), 1)))

อธิบายฟังก์ชัน

1. streak_range, O9:O39

• กำหนดช่วงข้อมูลที่ใช้เช็กสตรีค

2. last_val

• หา ค่าล่าสุดที่ไม่ว่าง ในช่วงนั้น → ใช้เพื่อดูว่า “วันล่าสุดเป็น 0 หรือ 1”

3. IF(last_val=0, 0, … )

• ถ้าวันล่าสุดเป็น 0 → สตรีค = 0 ทันที ถ้าเป็น 1 → ไปนับสตรีคต่อ

4. COUNTIF(OFFSET(...), 1)

เลื่อนช่วงลงไปที่ตำแหน่งที่เจอ 0 ล่าสุด แล้วนับจำนวน 1 ที่ต่อเนื่องหลังจากนั้น คือ “จำนวนวันที่ทำสำเร็จติดกันล่าสุด”

=MAX(SCAN(0, O9:O39, LAMBDA(a, v, IF(v=1, a+1, 0))))

อธิบายฟังก์ชัน

1. SCAN(0, O9:O39, LAMBDA(a, v, ...))

SCAN ไล่ดูค่าทีละเซลล์ในช่วง O9:O39

• a = ค่าสะสม (สตรีคก่อนหน้า)
• v = ค่าปัจจุบันในเซลล์

2. IF(v=1, a+1, 0)

• ถ้าเจอ 1 → เพิ่มสตรีคต่อเนื่อง
• ถ้าเจอ ไม่ใช่ 1 → รีเซ็ตเป็น 0

SCAN จะสร้างรายการสตรีคต่อเนื่องทั้งหมด เช่น 0,1,2,3,0,1,2,0,1 …

3. MAX(...)

เลือกค่าที่มากที่สุด → คือ สตรีคที่ยาวที่สุด

Step 4: เติมเต็มใจให้สปาร์กจอย (Weekly Check-ins & Reflections)

สร้าง Weekly Log เพื่อเช็กลิสต์รายการที่เราอยากทำ อาจเป็นกิจกรรมพิเศษอย่าง Spa Day, Movie Day หรือ Game Day เป้าหมายคือในหนึ่งสัปดาห์ เราอยากมีกิจกรรมที่ทำเพื่อตัวเองบ้าง

• สร้างตารางง่าย ๆ ระบุสัปดาห์ที่ 1 – 4
• ช่องกิจกรรม เลือก Insert > Dropdown จากนั้นเพิ่มรายการกิจกรรมที่เราอยากทำลงไปได้เลย อย่าลืมเลือกให้สามารถเลือกได้หลายข้อในช่องเดียวด้วยล่ะ

• ช่องเช็กลิสต์ เลือก Insert > Checkbox จากนั้นสร้าง Condition Formatting โดยลากคลุมตารางทั้งหมด และระบุ Format Rules เป็น > Custom Formula is… =$T9=TRUE
• เมื่อเราติ๊กถูก แถวในตารางก็จะไฮไลต์สีที่เลือกไว้ เป็นการเช็กว่าสัปดาห์นั้นเราได้ทำกิจกรรมตามที่ตั้งใจไว้หรือเปล่า

จากนั้นสร้าง Score Card เพื่อเป็นที่ว่างสำหรับเขียน Reflections ปิดท้ายหน้ารายเดือนด้วยการทำ reflections เพื่อสะท้อนความคิดเห็น ความรู้สึก สิ่งที่เราภูมิใจ หรือสิ่งที่เราอยากปรับปรุงในเดือนนั้น ๆ

Step 6: เชื่อมโยงข้อมูลสู่ภาพรวม (Data Consolidation)

ขั้นตอนสุดท้ายคือการทำความสะอาดข้อมูล (Data Cleaning) ในแต่ละเดือน เพื่อส่งต่อไปยังหน้า Annual_Dashboard

สรุปค่าเฉลี่ยของ Progress และ Mood ในแต่ละเดือนไว้ในตาราง เพื่อให้ Google Sheets และ Looker Studio สามารถดึงค่าไปใช้ต่อได้ทันที

• month: ต้องพิมพ์ชื่อเดือนใน cell ให้เหมือนชื่อ sheet จะได้ใช้สูตรดึงค่าจากแต่ละ sheet ต่าง ๆ มาใช้ได้

• date for looker: วันเดือนปีรูปแบบตัวเลข เพื่อให้ looker ดึงข้อมูลไปสร้าง dashboard ได้แบบไม่เพี้ยน

• yearly progress: ดึง monthly progress มาแสดงในตาราง ด้วยฟังก์ชัน

=IFERROR(INDIRECT(A2&"!Q2"), 0)

• mood score: ประเมินค่าเฉลี่ยจาก Emojis แทน Emojis แต่ละรูปด้วยคะแนนโดยใช้ฟังก์ชัน

=IFERROR(SUM(ARRAYFORMULA(SWITCH(INDIRECT(A2&"!L9:L39"), "😊", 5, "😐", 4, "😴", 3, "😫", 2, "😡", 1, 0))) / (COUNTIF(INDIRECT(A2&"!L9:L39"), "<>") * 5), 0)

• total 5 stars: นับวันที่เราได้ 5 ดาวว่ามีทั้งหมดกี่วัน

=IFERROR(COUNTIF(INDIRECT(A2&"!N9:N39"), 5), 0)

• mood: ใส่รูป Emojis เพื่อเตรียมเป็นข้อมูลทำ Dashbaord
• mood count: นับจำนวน Emojis ทั้งหมดโดยใช้ฟังก์ชัน

=COUNTIF(Jan!$L$9:$L$39, F2) + COUNTIF(Feb!$L$9:$L$39, F2) + COUNTIF(Mar!$L$9:$L$39, F2) + COUNTIF(Apr!$L$9:$L$39, F2) + COUNTIF(May!$L$9:$L$39, F2) + COUNTIF(Jun!$L$9:$L$39, F2) + COUNTIF(Jul!$L$9:$L$39, F2) + COUNTIF(Aug!$L$9:$L$39, F2) + COUNTIF(Sep!$L$9:$L$39, F2) + COUNTIF(Oct!$L$9:$L$39, F2) + COUNTIF(Nov!$L$9:$L$39, F2) + COUNTIF(Dec!$L$9:$L$39, F2

Step 8: สรุปภาพรวม (Yearly Insights & Visual Analytics)

เมื่อเราทำ sheet รายเดือนและตารางสรุปข้อมูลแล้ว ก็เตรียมทำ dashboard เพื่อแสดงผลข้อมูลรายปี

1. สร้าง Yearly Dashboard ใน Google Sheets

1. จัดวาง Layout (UI Design):
   • สร้างกล่องข้อความ (Shapes) 3 กล่องด้านบนสำหรับค่าสถิติสำคัญ (KPIs) ได้แก่ Yearly Progress, Mood Score, และ Total 5 Stars
   • ใช้พื้นหลังสีโทนเย็นเพื่อให้ Dashboard ดูสะอาดตา
2. ดึงข้อมูลสรุป (Data Linking):
   • Yearly Progress & Mood Score: ใช้สูตรดึงค่าเฉลี่ยจากหน้าสรุปรายเดือนมาแสดงผล
   • Total 5 Stars: ใช้สูตร SUM เพื่อนับจำนวนวันที่เราได้ 5 ดาว (Perfect Days) จากทั้ง 12 เดือน
3. สร้าง Mini Charts:
   • แทรกกราฟเส้น (Line Chart) เพื่อดูแนวโน้มความสัมพันธ์ระหว่างวินัยและอารมณ์รายเดือน
   • แทรกกราฟวงกลม (Donut Chart) เพื่อดูสัดส่วนอารมณ์ในภาพรวมตลอดทั้งปี

2. สร้างแดชบอร์ดสรุปภาพรวม ใน Looker Studio

​หลังจากที่เราเตรียมข้อมูลใน Google Sheets จนพร้อมแล้ว ขั้นตอนสุดท้ายคือการเปลี่ยนตัวเลขให้น่ามองและวิเคราะห์ง่ายขึ้นด้วย Looker Studio โดยเน้นไปที่การดูความสัมพันธ์ระหว่าง “วินัย” และ “อารมณ์”

Check out this dashboard HERE!

1. เชื่อมต่อข้อมูล
   • นำไฟล์ Google Sheets ของเราไป Connect กับ Looker Studio โดยเลือกเฉพาะ Sheet “Annual_Dashboard” ที่เราทำสรุปไว้
2. สร้าง Scorecards สรุปตัวเลขสำคัญ
   • สร้างตัวเลขภาพรวมปี เช่น Yearly Progress (%), Average Mood Score, และ Total 5 Stars Days อย่าลืมเช็กการตั้งค่า Aggregation (การรวมค่า) ให้เป็น Average สำหรับค่าเปอร์เซ็นต์ เพื่อให้ได้ค่าเฉลี่ยที่ถูกต้องของทั้งปี
3. กราฟเส้นคู่ดูความสัมพันธ์ (Dual-Axis Line Chart)
   • ใช้กราฟเส้นเพื่อดูว่าในแต่ละเดือน Progress กับ Mood เดินไปทางเดียวกันหรือไม่
   • ตั้งค่าแกนซ้ายเป็น % Progress และแกนขวาเป็น Mood Score (เพราะสเกลตัวเลขต่างกัน)
   • Insight: กราฟนี้จะช่วยตอบคำถามเราว่า “เดือนที่เราวินัยหลุด เป็นเพราะอารมณ์เราดิ่งลงด้วยหรือเปล่า?”
4. สัดส่วนอารมณ์ทั้งปี (Mood of the Year)
   • ใช้ Donut Chart สรุปว่าตลอดทั้งปีเรามีอารมณ์แบบไหนมากที่สุด
   • ใส่ตัวลอง (Filter) เพื่อเอา “ค่าว่าง (Null)” ออก ให้เหลือเฉพาะ Emojis อารมณ์ที่เราบันทึกไว้จริงๆ
   • ปรับสีแต่ละเสี้ยว (Slice) ให้คุมโทนตามความรู้สึก

Outcome

​การทำ Glow Up Tracker ไม่ได้เป็นแค่การจดบันทึก แต่คือการมองเห็น “ตัวเรา” ผ่านชุดข้อมูล (Data Visualization) ซึ่งช่วยให้เราใจดีกับตัวเองมากขึ้นในวันที่เหนื่อย และมีแรงผลักดันมากขึ้นในวันที่เห็นกราฟพุ่งทะยาน ส่วนของแถมก็คือสุขภาพกายและสุขภาพใจที่ดีขึ้นด้วย ☺️

Get Your Own Tracker

Download Glow Up Tracker HERE!